如何使用批处理实现自动登录QQ-创新互联

这篇文章给大家分享的是有关如何使用批处理实现自动登录QQ的内容。小编觉得挺实用的，因此分享给大家做个参考，一起跟随小编过来看看吧。

代码:
start "" "C:\Program Files\Tencent\QQ\qq.exe" /start QQUIN:843875648 PWDHASH:4Z1c1a8DeNoF9j+JHHRnrw== /stat:40引用:
10：上线登陆
40：隐身登陆
41：上线登陆
QQUIN和PWDHASH必须使用大写字母

原理：QQ在传输密码的时候，先做一次MD5加密，再做一次BASE64变换，这样可以得到正常的文本信息以便网络传输。找一个MD5在线查询的网站（比如http://www.xmd5.org/），输入QQ密码的明文，转换得到MD5加密的结果，再找一个BASE64在线查询的网站（比如http://www.waishi.net/ip/tools/base64.htm），输入刚才得到的MD5加密的结果，转换得到HASH编码即可。

使用VBS的SendKeys方法自动登录，因无法保证获取正确的交单，存在风险，因此不予考虑。经测试，目前无法用这个方法登陆新的QQ2009正式版，可能是新版的QQ未开启这个命令行接口吧，只能继续期待以后的版本了。

自动获取QQ路径的几种方法：读注册表、全盘搜索、获取进程信息等： 代码:

代码如下:

@echo off
rem 使用WMIC获取进程信息中的QQ路径
for /f "tokens=2 delims==" %%a in ('wmic process where "name='qq.exe'" get executablepath /value') do (
set QQPath=%%a
)
echo %QQPath%

pause代码:

代码如下:

@echo off
rem 使用WMIC全盘搜索获取QQ路径
for /f "skip=1 delims=" %%a in ('wmic datafile where "filename='qq' and extension='exe'" get name') do (
set QQPath=%%a
)
echo %QQPath%

pause代码:

代码如下:

@echo off
rem 使用reg命令读注册表获取QQ路径
for /f "tokens=2*" %%a in ('reg query HKEY_LOCAL_MACHINE\Software\Tencent\QQ /v Install^|findstr "Install"') do (
set QQPath=%%b
)
echo %QQPath%

pause代码:

代码如下:

@echo off
rem 使用reg export命令到处注册表项再搜索获取QQ路径以避免reg query可能存在的吃中文字符的问题
reg export "HKEY_LOCAL_MACHINE\SOFTWARE\Tencent\QQ" "%temp%\qq.txt">nul
for /f "tokens=2 delims==" %%a in ('type "%temp%\qq.txt"^|findstr /i "Install"') do (
rem 可以用 %%~fa 直接把字符串中的\\变成\
set QQPath=%%~a
)
set QQPath=%QQPath:\\=\%
echo %QQPath%

pause代码:

代码如下:

@echo off
rem 调用VBS读注册表获取QQ路径
>"%temp%\my.vbs" echo Set WshShell = WScript.CreateObject("WScript.Shell")
>>"%temp%\my.vbs" echo WScript.Echo WshShell.RegRead("HKEY_LOCAL_MACHINE\SOFTWARE\Tencent\QQ\Install")
for /f "delims=" %%a in ('cscript /nologo "%temp%\my.vbs"') do (
set QQPath=%%a
)
echo %QQPath%

pause代码:

代码如下:

@echo off
rem 全盘搜索获取QQ路径
set fName=qq.exe
for %%a in (C D E F G H I J K L M N O P Q R S T U V W X Y Z) do (
if exist %%a:\nul (
pushd %%a:\
for /r %%b in (%fName%?) do (
if /i "%%~nxb" equ "%fName%" (
set fPath=%%b
goto :show
)
)
popd
)
)
:show
echo %fPath%
pause

感谢各位的阅读！关于“如何使用批处理实现自动登录QQ”这篇文章就分享到这里了，希望以上内容可以对大家有一定的帮助，让大家可以学到更多知识，如果觉得文章不错，可以把它分享出去让更多的人看到吧！